-------------------------------------------------------------------------------
Gnuplot Hints and Tips

See...
  http://gnuplot.sourceforge.net/faq/faq.html

-------------------------------------------------------------------------------
Could not find/open font when opening font "arial", using internal
non-scalable font

Set the GDFONTPATH to the directories containing fonts
and set GNUPLOT_DEFAULT_GDFONT to the font you want to use
For example...
  setenv GDFONTPATH $HOME/lib/fonts/truetype/sets/
  setenv GNUPLOT_DEFAULT_GDFONT Verdana

You can also use GNUPLOT_FONTPATH but I have not got that to work.

-------------------------------------------------------------------------------
Generate a Blank page

  reset;
  unset xtics; unset ytics
  unset border;
  unset key
  set title 'Title on an empty page'
  plot [][0:1] 2

unset or set the above things as appropriate.

NOTE the border is different depending on if the title has been set or not.

-------------------------------------------------------------------------------
Generate a exact sized graph (no labels)

For example a plot image that is 300x200 pixels in size

First turn off all labels and other margin decorations, including
border.

  unset key
  set format ""
  unset border

Then set image size and no margins as follows.

  set term png size 300,200
  set lmargin at screen 0
  set bmargin at screen 0
  set rmargin at screen 0.99999
  set tmargin at screen 0.99999

The values of bottom and top margins is set to 0.9999 so that the
extreme limits of the X and Y range remains visible on the plot image.
Without it a Y value  1.0 will be clipped while a Y value of 0.9999
remains visible.  Basically the above makes the image 'inclusive' of the
upper limits of the any given X and Y range regardless of if the values
are integer or floating point.

You may also like to set the X and/or Y ranges of the plot to match up
to the actual pixel size of the image.  For example integer pixel
coordinates for X range and floating point range for Y

  set xrange [0:299]
  set yrange [0:1]
  plot ...

Note if the border is not unset (does not effect 'tics') then a border
is added along the bottom and left edges but not the top and right
edges.  Also this border overwrites and hides the lower range limit of
the graph! As such I recommend that you unset the border in gnuplot, and
provide a border around the outside of the generated image using
external image post-processing.


If for some reason you want to work with some white space around it,
and then later crop to final size:

  set term png size 330,220    # NB: 10% bigger than the final size
  set lmargin at screen 0.05
  set rmargin at screen 0.95
  set bmargin at screen 0.05
  set tmargin at screen 0.95

Curtisy of Ethan Merritt <merritt@u.washington.edu>
and the gnuplot-beta@lists.sourceforge.net mail list

-------------------------------------------------------------------------------
Plot a 'iso-line' from a surface
Also known as a 'implicit defined graph'

The trick is to draw the single contour line z=0 of the surface z=f(x,y), and
store the resulting contour curve to a gnuplot table datafile.  This data file
can then be plotted.

# An example. Place your definition in the following line:
f(x,y) = y - x**2 / tan(y)
set contour base
set cntrparam levels discrete 0.0
unset surface
set table 'curve.dat'
splot f(x,y)
unset table
plot 'curve.dat' w l

Question, can you plot an iso line of an image?  If so we shoud be able to
generate vector edges of shapes.  A sort of vectorization program.

This could also be used for plotting the bounds of EWA (Elliptical Weighted
Area)  Resampling!

-------------------------------------------------------------------------------